Android/settings.gradle at 61e9eb50a857cab5cb4b6e9af2e36de187f876df · nikit19/Android · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
plugins {
    id("de.fayard.refreshVersions") version "0.23.0"
}

include ':browser-api'
include ':vpn'
include ':vpn-store'
include ':vpn-main'
include ':vpn-api'
include ':vpn-internal'
include ':di'
include ':app'
include ':statistics'
include ':common'
include ':common-ui'
include ':app-store'

include ':feature-toggles-api'
include ':feature-toggles-impl'

include ':privacy-config-api'
include ':privacy-config-impl'
include ':privacy-config-store'

include ':traces-api'
include ':traces-impl'

include ':common-test'

project(':feature-toggles-api').projectDir = new File('feature-toggles/feature-toggles-api')
project(':feature-toggles-impl').projectDir = new File('feature-toggles/feature-toggles-impl')
project(':privacy-config-api').projectDir = new File('privacy-config/privacy-config-api')
project(':privacy-config-impl').projectDir = new File('privacy-config/privacy-config-impl')
project(':privacy-config-store').projectDir = new File('privacy-config/privacy-config-store')

project(':traces-api').projectDir = new File('traces/traces-api')
project(':traces-impl').projectDir = new File('traces/traces-impl')

rootProject.children.each { subproject ->

    if (subproject.name == "vpn") {
        subproject.buildFileName = "${subproject.name}-build.gradle"
    }
}


buildCache {

    def getFile = { dir, filename ->
        File file = new File("$dir$File.separator$filename")
        file?.exists() ? file : null
    }

    def getLocalProperties = { dir ->
        def file = getFile(dir, "local.properties")
        if (!file) {
            return null
        }

        Properties properties = new Properties()
        properties.load(file.newInputStream())
        return properties
    }

    local {
        def properties = getLocalProperties(rootDir)
        if (properties != null) {
            enabled = "true" == properties.getProperty("local.build.cache", "true")
        } else {
            enabled = true
        }
        // configure local build cache directory so that it is local to the project dir
        directory = new File(rootDir, 'build-cache')
        removeUnusedEntriesAfterDays = 7
    }
}